CB Repository

// TARVITTAVA GLOBAALI MUUTTUJA
Global gPlayImageRec
gPlayImageRec=0

// ESIMERKKI
anim=LoadAnimImage("Media/note.bmp",32,32,0,8) 
MaskImage anim,cbmagenta

speed = 100

Repeat

    speed = speed + MouseMoveZ()*2
    
    x = x + (RightKey() - LeftKey()) * 4
    y = y + (DownKey() - UpKey()) * 4
    
    frame = PlayImage( anim, frame, x, y, 0, 8, speed )
    
    Text 5, 200, "X: "+x
    Text 5, 215, "Y: "+y
    Text 5, 230, "Framen nopeus: "+speed + "ms"
    Text 5, 245, "Vaihda nopeutta hiiren rullalla. Liikuta"
    Text 5, 260, "kuvaa nuolinäppäimillä."
    
    DrawScreen
    
Forever

//***********************************************************************
// PlayImage()-funktio by VesQ
// Funktio kuvasarjan toistamista varten.
//
// Huomaa, että funktion paluuarvo pitää ottaa talteen ja antaa
// saatu arvo funktiolle uudelleen _frame -parametriin. Katso esimerkki.
//
// Funktio tarvitsee toimiakseen globaalin kokonaislukumuuttujan 
// gPlayImageRec, jonka avulla ajastin toimii.
//
// Parametrien selitys:
//  _img         = LoadAnimImage()-funktiolla ladattu kuvamuuttuja
//  _frame       = Tällä hetkellä menevä frame. TÄRKEÄ!
//  _x#          = Kuvan x-koordinaatti
//  _y#          = Kuvan y-koordinaatti
//  _framefirst  = Mistä kohtaa animaatiota aloitetaan.
//  _framelast   = Mikä on viimeinen frame animaatiossa.
//  _speed       = yhden framen kesto millisekunteina. Oletus 100
//  _transperency= Läpinäkyvyys OFF/ON. Oletuksena normaali läpinäkyvyys
//***********************************************************************
Function PlayImage( _img, _frame, _x#, _y#, _framefirst, _framelast, _speed=100, _transparency=1 )
    
    If _frame < _framefirst Then _frame = _framefirst
    DrawImage _img, _x, _y, _frame, _transparency
    
    If gPlayImageRec=0 Then gPlayImageRec=Timer()
    If Timer() > gPlayImageRec + _speed Then
        gPlayImageRec = 0
        If _frame >= _framelast-1 Then Return _framefirst Else Return _frame+1
    EndIf
    
    Return _frame
EndFunction